Kmitočtové a přenosové charakteristiky

>    restart;

Definice přenosové funkce

>    H:=1/(s^2+sqrt(2)*s+1);

H := 1/(s^2+2^(1/2)*s+1)

Dosazení za Laplaceův operátor s  (toto značení je "anglické", u nás obvykle používáme označení p ) komplexní kmitočet I*omega .

>    H_f:=subs(s=I*omega,H);

H_f := 1/(-omega^2+2^(1/2)*omega*I+1)

Výpočet modulu.

>    AH:=evalc(abs(H_f));

AH := 1/((omega^4+1)^(1/2))

Definice fáze jako funkce - pro procvičení.

>    PH:=unapply(evalc(argument(H_f)),omega);

PH := proc (omega) options operator, arrow; arctan(-2^(1/2)*omega,-omega^2+1) end proc

Modulová frekvenční charakteristika.

>    plot(AH,omega=0..3);

[Maple Plot]

Fázová frekvenční charakteristika ve stupních.

>    plot(PH(omega)*180/Pi,omega=0..3);

[Maple Plot]

Počítání s logaritmy

Přirozený logaritmus

>    ln(10.0);

2.302585093

Obecný logaritmus - standartně přirozený

>    log(10.0);

2.302585093

>    log[exp(1)](10.0);

2.302585093

Volitelně desítkový

>    log[10](10.0);

1.000000000

Desítkový logaritmus

>    log10(10.0);

1.000000000

Modulová charakteristika v dB

>    plot(20*log10(AH),omega=0..3);

[Maple Plot]

Modulová charakteristika s logaritmickým měřítkem na ose kmitočtu.

>    plots[semilogplot](20*log10(AH),omega=0.1..10);

[Maple Plot]

Fázová chrakteristika. Logaritmické měřítko na ose x (kmitočtu) je uděláno jiným způsoem.

>    plot(PH(10^x),x=-1..1);

[Maple Plot]

Použití funkce semilogplot dává špatné výsledky - nerovnoměrně rozdělené body, což je patrné zejména pro velký rozsah hodnot kmitočtu.

>    plots[semilogplot](PH(omega),omega=0.01..100,style=point);

[Maple Plot]

S několika dalšími parametry můžeme výsledek opravit.

>    plots[semilogplot](PH(omega),omega=0.01..100,style=point,sample=[seq(10^(i/10),i=-20..20)],adaptive=false);

[Maple Plot]

Zpět na začátek sekce .