Důkaz uvedených skutečností

Nejdříve nahradíme do vztahu pro přenos výraz omega1[n]    za omega[n]  - pro výpočty je nutné rozlišit omega[n]  a omega  ( omega[n]  je jen n-tá položka proměnné omega ).

>    Pk1:=K/expand(subs({p1=sigma[n]+I*omega1[n],p2=sigma[n]-I*omega1[n]},denom(P)));   

Pk1 := K/(p^2-2*p*sigma[n]+sigma[n]^2+omega1[n]^2)

dosadíme za p = I*omega  a vypočteme absolutni hodnotu prenosu

>    abs_Pk1:=evalc(abs(subs(p=I*omega,Pk1)));

abs_Pk1 := (K^2*(-omega^2+sigma[n]^2+omega1[n]^2)^2/((-omega^2+sigma[n]^2+omega1[n]^2)^2+4*omega^2*sigma[n]^2)^2+4*K^2*omega^2*sigma[n]^2/((-omega^2+sigma[n]^2+omega1[n]^2)^2+4*omega^2*sigma[n]^2)^2)^(...

a hledáme maximum funkce abs_Pks  -- řešíme následující rovnici  

>    Diff('abs_Pk1',omega)=0;
reseni:=solve(diff(abs_Pk1,omega),omega);

Diff(abs_Pk1,omega) = 0

reseni := 0, (-sigma[n]^2+omega1[n]^2)^(1/2), -(-sigma[n]^2+omega1[n]^2)^(1/2)

Derivace je nulová samozřejmě v bodě omega = 0 , a dále pro kmitočet omega[r] = sqrt(-sigma[n]^2+omega[n]^2)  , pro který nastává maximum na modulové charakteristice (záporné kmitočty samozřejmě nelze uvažovat). Tento kmitočet nazvěme omega[r] . Z jeho vyjádření lze vyčíst, že "překmit" na modulové chrakteristice nastává pouze pro sigma[n] < omega[n]  , ( 1/sqrt(2) < Q ). Jeli sigma[n] = 0 , jedná se o případ čistě imaginárních kořenů a kmitočet vlastních kmitů , omega[n]  se rovná zlomovému kmitočtu omega[0] . O zlomovém kmitočtu však v tomto případě nelze hovořit -- jde o systém na mezi stability, jak je ukázáno dále (čtvrtý případ). Čím více se hodnota omega[n]  blíží hodnotě sigma[n]  vzdaluje se omega[r]  od zlomového kmitočtu omega[0]  směrem k bodu omega = 0  "a překmit se zmenšuje". Je-li sigma[n] = omega[n]  , ( Q = 1/sqrt(2) ) překmit zaniká ( omega[r] = 0 ) a to je právě případ maximálně ploché charakteristiky. Jestliže je omega[n] < sigma[n]  , ( Q < 1/sqrt(2) ) nelze o extrému hovořit, jelokož nastává na komplexním (nereálném) kmitočtu. To si může zvídavý čtenář ověřit na pomocí 3D grafu. To je také případ dvojice reálných kořenů, kdy platí vždy omega[n] < sigma[n]  (viz pravou část náčrtu).   

>    modul1:=evalc(abs(subs({Q=2,omega[0]=1000,K=1000000,p=I*omega},Pkq))):
modul2:=evalc(abs(subs({Q=1,omega[0]=1000,K=1000000,p=I*omega},Pkq))):
modul3:=evalc(abs(subs({Q=1/sqrt(2),omega[0]=1000,K=1000000,p=I*omega},Pkq))):
modul4:=evalc(abs(subs({Q=0.5,omega[0]=1000,K=1000000,p=I*omega},Pkq))):
modul5:=evalc(abs(subs({Q=0.2,omega[0]=1000,K=1000000,p=I*omega},Pkq))):
pl1:=semilogplot(20*log10(modul1),omega=1..3000,thickness=3,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],color=red):
pl2:=semilogplot(20*log10(modul2),omega=1..3000,thickness=3,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],color=green):
pl3:=semilogplot(20*log10(modul3),omega=1..3000,thickness=3,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],color=blue):
pl4:=semilogplot(20*log10(modul4),omega=1..3000,thickness=3,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],color=maroon):
pl5:=semilogplot(20*log10(modul5),omega=1..3000,thickness=3,title=`Modulová charakteristika pro Q=2, 1, 0.707, 0.5 a 0.2`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],color=black):
t1 := textplot([3,-22,`omega_0`]):
t2 := textplot([2.6,-8,`Q=0.2`],align=LEFT):
t3 := textplot([2.82,-4,`0.5`],align=LEFT):
t4 := textplot([2.87,2.3,`1`]):
t5 := textplot([3.1,4,`Q=2`],align=RIGHT):
t6 := textplot([1,-2.8,`-3dB`],align=ABOVE):
t7 := textplot([1,-5.8,`-6dB`],align=ABOVE):
l1:=line([3,6],[3,-20],color=black,linestyle=2):
l2:=line([0,-3],[3.5,-3],color=black,linestyle=2):
l3:=line([0,-6],[3.5,-6],color=black,linestyle=2):
display(pl1,pl2,pl3,pl4,pl5,l1,l2,l3,t1,t2,t3,t4,t5,t6,t7);

[Maple Plot]

>    faze1:=evalc(argument(subs({Q=2,omega[0]=1000,K=1000000,p=I*omega},Pkq))):
faze2:=evalc(argument(subs({Q=1,omega[0]=1000,K=1000000,p=I*omega},Pkq))):
faze3:=evalc(argument(subs({Q=1/sqrt(2),omega[0]=1000,K=1000000,p=I*omega},Pkq))):
faze4:=evalc(argument(subs({Q=0.5,omega[0]=1000,K=1000000,p=I*omega},Pkq))):
faze5:=evalc(argument(subs({Q=0.2,omega[0]=1000,K=1000000,p=I*omega},Pkq))):
ph1:=semilogplot(180/Pi*faze1,omega=1..3000,thickness=3,numpoints=300,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],color=red):
ph2:=semilogplot(180/Pi*faze2,omega=1..3000,thickness=3,numpoints=300,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],color=green):
ph3:=semilogplot(180/Pi*faze3,omega=1..3000,thickness=3,numpoints=300,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],color=blue):
ph4:=semilogplot(180/Pi*faze4,omega=1..3000,thickness=3,numpoints=300,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],color=maroon):
ph5:=semilogplot(180/Pi*faze5,omega=1..3000,thickness=3,numpoints=300,title=`Fázová charakteristika pro Q=2, 1, 0.707, 0.5 a 0.2`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],color=black):
t1 := textplot([2.98,-20,`Q=2`]):
t2 := textplot([1.8,-30,`Q=0.2`]):
display(ph1,ph2,ph3,ph4,ph5,t1,t2);

[Maple Plot]

P ro případ sigma[n] = omega[n]  si ještě ověříme polohu zlomového kmitočtu a velikost poklesu modulové charakteristiky pro tento kmitočet.

>    Pk;

K/(p^2-2*p*sigma[n]+sigma[n]^2+omega[n]^2)

 Dosadíme do jmenovatele přenosu sigma[n] = omega[n]  a nalezneme póly přenosu.

>    omega0:=solve(subs(sigma[n]=omega[n],denom(Pk)),p);

omega0 := (1+I)*omega[n], (1-I)*omega[n]

 Póly musí být komplexně združené a jejich velikost musí být rovna omega[0] = sqrt(sigma[n]^2+omega[n]^2) , což pro náš případ vyjde.

>    omega0_abs:=abs(omega0[1]);

omega0_abs := 2^(1/2)*abs(omega[n])

>   

 Nyní vypočteme absolutní hodnotu přenosu pro omega = omega[0] . Abychom dostali požadovaný výsledek, je nutno opět zavést předpoklad 0 < omega[n] .

>    'Pks'=abs(subs({p=I*omega0_abs,sigma[n]=omega[n]},Pk));
Pkn:=simplify(rhs(%)) assuming omega[n]>0;

Pks = abs(K/(-2*abs(omega[n])^2-2*I*2^(1/2)*abs(omega[n])*omega[n]+2*omega[n]^2))

Pkn := 1/4*2^(1/2)/omega[n]^2*abs(K)

 Dále vypočteme hodnotu přenosu pro nulový kmitočet - "asyptotická" hodnota přenosu.

>    Pk0:=abs(Limit(Pk,p=0)); Pk0:=value(Pk0);

Pk0 := abs(Limit(K/(p^2-2*p*sigma[n]+sigma[n]^2+omega[n]^2),p = 0))

Pk0 := abs(K/(sigma[n]^2+omega[n]^2))

 Nyní již lze určit pokles přenosu ve zlomovém kmitočtu.

>    'Pkn/Pk0'=simplify(Pkn/subs(sigma[n]=omega[n],Pk0)) assuming omega[n]>0;
'Pkn/Pk0'=evalf(20*log10(rhs(%)));       # pokles v [dB]

1/4*2^(1/2)/omega[n]^2*abs(K)/abs(K/(sigma[n]^2+omega[n]^2)) = 1/2*2^(1/2)

Pkn/Pk0 = -3.010299958

Což je výsledek který již známe z průběhu maximálně ploché modulové charakteristiky. Podíl skutečného modulu při zlomovém kmitočtu a jeho "asymptotické" hodnoty je také roven činiteli jakosti, jak bylo výše uvedeno. Tuto skutečnost lze jednoduše dokázat i pro obecný případ.

>    Pkq;

K/(p^2+p*omega[0]/Q+omega[0]^2)

Dosaďme za omega = omega[0]  (zlomový kmitočet) do výrazu pro modul přenosu.

>    Pkz:=abs(subs(p=I*omega[0],Pkq));

Pkz := abs(K/omega[0]^2*Q)

Tuto hodnotu vydělme "asymtotickou" hodnotou přenosu a dostaneme:

>    'Pkz/Pk0'=simplify(subs(omega[0]=sqrt(sigma[n]^2+omega[n]^2),Pkz)/Pk0);

Pkz/Pk0 = abs(Q)

Jelikož je 0 < Q  , je to důkaz našeho tvrzení. Nyní následuje dokončení výkladu .