Nuly přenosových funkcí

©  Jiří Hospodka

Autorská práva: Uživatel může tento text používat jako studijní materiál bez omezení. Distribbuce a tisk je možný pouze se svolením autora.

Tato kapitola bezprostředně navazuje na kapitolu , zabývající vlivem pólů přenosových funkcí lieárního systému na jeho vlastnosti v kmitočtové a časové oblasti.
restart:

Pro výpočty a kreslení někrerých grafů budeme potřebovat tyto knihovny.

>    with(inttrans):with(plots):

Warning, the name changecoords has been redefined

U přenosových funkcí obsahujících nuly přenosu, je nutné si uvědimit jednu důležitou skutečnost. Přenosová funkce se totiž nemůže skládat pouze z jedné nebo více nul, ale vždy musí mít i odpovídající počet pólů přenosu, resp. je-li přenosová funkce ve tvaru racionálně lomenné funkce musí být být stupeň čitatele nižší než stupeň jmenovatele.  

Vysvětlení lze podat dvěma způsoby:

Pokusíme-li se přesto najít předmět např. funkce 1. Víme, že předmětem je Diracova funkce, tj. není funkce standardního typu (není to také reálný signál).

>    invlaplace(1,p,t);

Dirac(t)

>    Int(Dirac(t),t = -infinity..infinity):%=value(%);

Int(Dirac(t),t = -infinity .. infinity) = 1

Obvodem, jež v ideálním případě nebude mít žádný pól kmitočtově závislého přenosu, může být např. derivátor . Ten je ukázán na následujícím obrázku. Jeho přenos je roven F(p) = U2(p)/U1(p)   a po vyjádření dostaneme F(p) = -C*R2*(p+1/(C*R1))  .   

                                                                                 [Maple OLE 2.0 Object]

Budeme-li hledat předmet k Laplaceovu obrazu typu K*(p-p0)  , dojdeme k následujícímu výsledku.

>    invlaplace(K*(p-p0),p,t);

K*(Dirac(1,t)-p0*Dirac(t))

Zde je ukázáno, co je míněno zápisem Dirac(1,t) . Je to zřejmě  derivace Diracovy funkce, což je opět nereálný signál.  

>    Diff(Heaviside(t),t):%=value(%);

>    Diff(Dirac(t),t):%=value(%);

>    Diff(Dirac(1,t),t):%=value(%);

Diff(Heaviside(t),t) = Dirac(t)

Diff(Dirac(t),t) = Dirac(1,t)

Diff(Dirac(1,t),t) = Dirac(2,t)

Je nutné si však uvědomit, že v případě realizace takovéhoto zapojení, tj, při použití reálného operačního zesilovače nedostaneme, vlivem  kmitočtové závislosti jeho zesílení, pro přenos výše uvedený vztah. V reálných podmínkách bude tedy vždy platit, že supeň čitatele je nižší než stupeň jmenovatale .

Věnujme se však ještě dalšímu idealizovanému případu, kdy je stupeň čitatele i jmenovatele přenosové funkce shodný a tudíž je přenos takovéhoto systému nenulový i pro omega = infinity , což nelze v praxi realizovat. Uvedený případ demonstrujme na přenosu, který obsahuje jednu nulu i pól  v levé polorovině komplexní roviny   p .

>    P:=K*(p-p1)/(p-p2);

P := K*(p-p1)/(p-p2)

Nula v levé polorovině

 Např. pro   p1 = -1000 , p2 = -100  a K = 1/11  dostaneme

>    pp:=abs(subs({K=1/11,p1=-1000,p2=-100,p=sigma+I*omega},P));

pp := 1/11*abs((sigma+omega*I+1000)/(sigma+omega*I+100))

V našem případě by mohl obvod realizující takovýto přenos vypadat například tak, jak je ukázáno na tomto obrázku.

                                                                                                 [Maple OLE 2.0 Object]

Závislost přenosu na komplexním kmitočtu p = sigma+j*omega  je vynesena na následujícím obrázku. Pro větší dynamiku je přenos vykreslen v dB.

>    Surface:=plot3d(20*log10(pp),omega=1..1000,sigma=-2000..500,style=patchnogrid,axes=box,orientation=[140,52],numpoints=1000):
curve_o:=[omega,0,20*log10(subs(sigma=0,pp))]:
B_o:=spacecurve(curve_o,omega=1..1000,axes=none,color=black,thickness=3):
display(Surface,B_o,labels=[omega,sigma,`log|pp|`],title=`Modul přenosu v závislosti na "kompexním kmitočtu" p`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8]);

[Maple Plot]

Tvar modulové charakteristiky opět dostaneme jako řez pro sigma = 0  tak, jak je zvýrazněno. Její průběh v logatirmickém měřítku kmitočtu je vynesen na dalším grafu. Je zde také fázová charaktristika, která má na první pohled nezvyklý tavar, který je dán poměrně blízkým umístěním pólu a nuly přenosu. (Fáze přenosu začíná na 0^o , potom díky pólu přenosu klesá a dále vlivem nuly přenosu opět stoupá až na 0^o ).

>    plot(subs(sigma=0,pp),omega=10..5000,title=`Modulová charakteristika s lineárním měřítkem kmitočtu [dB]`,labels=[omega,`|pp|`],labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],thickness=3);
semilogplot(20*log10(subs(sigma=0,pp)),omega=10..5000,title=`Modulová charakteristika s logaritmickým měřítkem kmitočtu [dB]`,labels=[omega,`log|pp|`],axes=FRAME,labelfont=[HELVETICA,8], axesfont=[HELVETICA,8],thickness=3);
semilogplot(180/Pi*argument(subs({K=1/11,p1=-1000,p2=-100,p=I*omega},P)),omega=5..5000,title=`Fázová charakteristika s logaritmickým měřítkem kmitočtu [deg]`,labels=[omega,`Arg(pp)`], axes=FRAME,labelfont=[HELVETICA,8], axesfont=[HELVETICA,8],thickness=3);

[Maple Plot]

[Maple Plot]

[Maple Plot]

Následuje výpočet odezvy obvodu na Dirakův impulz - impulzní charakteristika.  

>    pt:=invlaplace(P, p, t);
Re_pt:=evalc(Re(subs({K=1/11,p1=-1000,p2=-100},pt)));
Im_pt:=evalc(Im(subs({K=1/11,p1=-1000,p2=-100},pt)));
plot(subs({K=1/11,p1=-1000,p2=-100},pt),t=0.00001..0.05,title=`Impulzní charakteristika`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],thickness=3);

pt := K*(Dirac(t)-exp(p2*t)*p1+exp(p2*t)*p2)

Re_pt := 1/11*Dirac(t)+900/11*exp(-100*t)

Im_pt := 0

[Maple Plot]

Je patrné, že ve výstupním signálem je opět Dirakův impulz, proto také není impulzní charakteristika vykreslena od t = 0 , kde výstup roste nadevšechny meze. To je pochopitelné, jelikož stupeň čitatele i jmenovatele přenosu je shodný. Ve skutečnosti však vlivem prarazitních kapacit a indukčností vodičů bude přenos vykazovat další póly právě v oblasti velmi vysokých kmitočtů a tudíž i odezva na nereálný vstupní signál (Diracův impulz) bude dávat na výstupu reálný signál. Toto je, jak jsme uvedli na začátku, pouze idealizovaný případ, ktrerý však pro oblasti relativně nízkých kmitočtů dává objektivní výsledky.

Daleko zajímavější je skutečnost, že poloha nuly přenosu neovlivní charakter časové odezvy pt  (exponenciální, kmitavá), ale v exponentu, který tento charakter určuje, je přítomný pouze pól přenosu. To je velmi důležité a vyplývá to z předchozího výkladu ( odezva.mws). Poloha nuly nemá tedy vliv na stabilitu pbvodu a tudíž se u stabilního systému může objevit jak v levé, tak i v pravé polorovině komplexní roviny, což si ukážeme dále.

Pro úplnost je zařazen i výpočet přechodové charakteristiky.

>    pt:=invlaplace(P*1/p, p, t);
Re_pt:=evalc(Re(subs({K=1/11,p1=-1000,p2=-100},pt)));
Im_pt:=evalc(Im(subs({K=1/11,p1=-1000,p2=-100},pt)));
plot(subs({K=1/11,p1=-1000,p2=-100},pt),t=0..0.05,title=`Přechodová charakteristika`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],thickness=3);

pt := K*(-exp(p2*t)*p1/p2+exp(p2*t)+p1/p2)

Re_pt := -9/11*exp(-100*t)+10/11

Im_pt := 0

[Maple Plot]

Nula v pravé polorovině

  Např. pro   p1 = 1000 , p2 = -100  a K = 1/11  dostaneme

>    pp:=abs(subs({K=1/11,p1=1000,p2=-100,p=sigma+I*omega},P));

pp := 1/11*abs((sigma+omega*I-1000)/(sigma+omega*I+100))

V našem případě by mohl obvod realizující takovýto přenos vypadat například tak, jak je ukázáno na tomto obrázku.  Všimněte si, že se jedná o "aktivní obvod" - obsahuje řízený zdroj (v našem případě zdroj proudu řízený napětím). Tento obvod se navíc poměrně často vyskytuje v linearizovaných obvodech různých zesilovačů, tudíž se nejedná o žádný vykonstruovaný příklad.. Pasivní obvod složený pouze s rezistorů, kapacitorů a induktorů má všechny nuly přenosu v levé polorovině (jde o obvod s minimální fází). Odvození této skutečnosti není opět naším cílem a zvídavého čtenáře odkážeme na příslušnou literaturu.

[Maple OLE 2.0 Object]

Závislost přenosu na komplexním kmitočtu p = sigma+j*omega  je vynesena na následujícím obrázku.

>    Surface:=plot3d(20*log10(pp),omega=1..1000,sigma=-1000..2000,style=patchnogrid,axes=box,orientation=[140,64],numpoints=2000):
curve_o:=[omega,0,20*log10(subs(sigma=0,pp))]:
B_o:=spacecurve(curve_o,omega=1..1000,axes=none,color=black,thickness=3):
display(Surface,B_o,labels=[omega,sigma,`log|pp|`],title=`Modul přenosu v závislosti na "kompexním kmitočtu" p`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8]);

[Maple Plot]

Tvar modulové charakteristiky se oproti předchozímu případu nezmění. Rozdíl však nastává v charakteristice fázové. Oproti minulému případu zde fáze přenosu začíná na 180^o  (obvod otáčí pro stejnosměrný signál fázi), potom díky pólu přenosu klesá a dále vlivem nuly přenosu stále klesá až na 0^o . To je velmi důležité si uvědomit - nula vpravo má na fázovou charakteristiku stejný vliv jako pól přenosu, ale tvar modulové charakteristiky je stejný jako by tato nula ležela v levé polotovině komplexní roviny . Tento poznatek využijeme hlavně tehdy, až se budeme zabývat stabilitou zpětnovazebních soustav, kde jak uvidíme je tato otázka velmi důležitá.

>    semilogplot(20*log10(subs(sigma=0,pp)),omega=10..5000,title=`Modulová charakteristika s logaritmickým měřítkem kmitočtu [dB]`,labels=[omega,`log|pp|`],axes=FRAME,labelfont=[HELVETICA,8], axesfont=[HELVETICA,8],thickness=3);
semilogplot(180/Pi*argument(subs({K=1/11,p1=1000,p2=-100,p=I*omega},P)),omega=10..5000,title=`Fázová charakteristika s logaritmickým měřítkem kmitočtu [deg]`,labels=[omega,`Arg(pp)`], axes=FRAME,labelfont=[HELVETICA,8], axesfont=[HELVETICA,8],thickness=3);

[Maple Plot]

[Maple Plot]

Na stabilitě takovéto soustavy se nic nezmění, jak ukazují následující výpočty a jak bylo řečeno již v předchozím výkladu.  

>    pt:=invlaplace(P, p, t);
Re_pt:=evalc(Re(subs({K=1/11,p1=1000,p2=-100},pt)));
Im_pt:=evalc(Im(subs({K=1/11,p1=1000,p2=-100},pt)));
plot(subs({K=1/11,p1=1000,p2=-100},pt),t=0.00001..0.05,title=`Impulzní charakteristika`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],thickness=3);

pt := K*(Dirac(t)-exp(p2*t)*p1+exp(p2*t)*p2)

Re_pt := 1/11*Dirac(t)-100*exp(-100*t)

Im_pt := 0

[Maple Plot]

Odezva na Dirakův impulz - impulzní charakteristika se až na znaméko velmi podobá předchzímu příkladu (ve skutečnosti se změnilo zanaménko i velikost násobné konstakty exponenciely). Po odeznění přechodového jevu se systém opět ustálí a výstupní signál zaniká - obvod je stabilní.    

Podobně se změní i chrakteristika přechodová.

>    pt:=invlaplace(P*1/p, p, t);
Re_pt:=evalc(Re(subs({K=1/11,p1=1000,p2=-100},pt)));
Im_pt:=evalc(Im(subs({K=1/11,p1=1000,p2=-100},pt)));
plot(subs({K=1/11,p1=1000,p2=-100},pt),t=0..0.05,title=`Přechodová charakteristika`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],thickness=3);

pt := K*(-exp(p2*t)*p1/p2+exp(p2*t)+p1/p2)

Re_pt := exp(-100*t)-10/11

Im_pt := 0

[Maple Plot]

Nula v nule (pro nulový kmitočet)

>    P:=K*p/(p-p1);

P := K*p/(p-p1)

  Např. pro   p1 = -1000  a K = 1  dostaneme

>    pp:=subs({K=1,p1=-1000,p=sigma+I*omega},P);

pp := (sigma+omega*I)/(sigma+omega*I+1000)

Toto je příklad přenosu obvodu, který vykazuje nulový přenos pro stejnosměrný signál -- střídavě vázané systémy (např. pomocí oddělovacích kondenzátorů. Takový přenos lze realizovat jednoduchým derivačním RC článkem.  

[Maple OLE 2.0 Object]

Závislost přenosu na komplexním kmitočtu p = sigma+j*omega  je vynesena na následujícím obrázku.

>    Surface:=plot3d(20*log10(abs(pp)),omega=1..500,sigma=-1000..800,style=patchnogrid,axes=box,orientation=[119,64],numpoints=2000):
curve_o:=[omega,0,20*log10(subs(sigma=0,abs(pp)))]:
B_o:=spacecurve(curve_o,omega=1..500,axes=none,color=black,thickness=3):
display(Surface,B_o,labels=[omega,sigma,`|pp|`],title=`Modul přenosu v závislosti na "kompexním kmitočtu" p`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8]);

[Maple Plot]

Kmitočtové charakteristiky vycházejí podle předpokladu. Modulová chrakteristika stoupá z nulového přenosu pro nulový kmitočet (pozor na log. měřítka) až do oblasti, kdy se začne ulpatňovat vliv pólu přenosu. Fázová charakteristika přenosu začíná díky nule na 90^o  a potom díky pólu přenosu klesá na 0^o .

>    semilogplot(20*log10(subs(sigma=0,abs(pp))),omega=100..10000,title=`Modulová charakteristika s logaritmickým měřítkem kmitočtu [dB]`,labels=[omega,`log|pp|`],axes=FRAME,labelfont=[HELVETICA,8], axesfont=[HELVETICA,8],thickness=3);
semilogplot(180/Pi*argument(subs(sigma=0,pp)),omega=100..10000,title=`Fázová charakteristika s logaritmickým měřítkem kmitočtu [deg]`,labels=[omega,`Arg(pp)`], axes=FRAME,labelfont=[HELVETICA,8], axesfont=[HELVETICA,8],thickness=3);

[Maple Plot]

[Maple Plot]

Jak bylo řečeno, nuly přenosu neovlivňují charakter časové odezvy a tudíž i zde se na stabilitě takovéto soustavy se nic nezmění. V tomto jednoduchém případě lze navíc velmi dobře odhadnout jak tvar impulzové, tak přechodové charakteristiky.

>    pt:=invlaplace(P, p, t);
Re_pt:=evalc(Re(subs({K=1,p1=-1000},pt)));
Im_pt:=evalc(Im(subs({K=1,p1=-1000},pt)));
plot(subs({K=1,p1=-1000},pt),t=0.00001..0.01,title=`Impulzní charakteristika`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],thickness=3);

pt := K*(Dirac(t)+p1*exp(p1*t))

Re_pt := Dirac(t)-1000*exp(-1000*t)

Im_pt := 0

[Maple Plot]

>    pt:=invlaplace(P*1/p, p, t);
Re_pt:=evalc(Re(subs({K=1,p1=-1000},pt)));
Im_pt:=evalc(Im(subs({K=1,p1=-1000},pt)));
plot(subs({K=1,p1=-1000},pt),t=0..0.01,title=`Přechodová charakteristika`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],thickness=3);

pt := K*exp(p1*t)

Re_pt := exp(-1000*t)

Im_pt := 0

[Maple Plot]

Nyní již známe téměř všechy možné případy, které se mohou v přenosech lineárních nebo linearizovaných soustav vyskytnout. Pro úplnost zde chybí ještě případ komlexně sdružené dvojice nul přenosu. Jelikož však ta nemá vliv na stabilitu obvodu, je situace daleko jednodužší než tomu bylo v případě pólů přenosu. Vliv na kmitočtové charakteristiky je u koplexně sdružených nul přesně inverzní (zrcadlově převrácený podle osy omega ) oproti koplexně sdruženým pólům, tudíž známý. Rozdíl je pouze v případě nul v pravé polorovině, kde modulová charakteristika zůstává inverzní, ale fázová chrakteristika je shodná jako v případě pólů. O příspěvcích jednotlivých pólů na celkové vlastnosti (v kmitočtové oblasti) jsme hovořili na závěr minulé kapitoly ( aeo_pol.mws). Tyto poznatky samozřejmě platí i zde, pro přenosy obsahující jak póly tak nuly.

Na závěr uvedeme pro úplnost dva příklady. První ukazuje vlastnosti přenosu obsahující jenu nulu (v pravé nebo levé polorovině) a koplexně sdružený pól. Druhý příklad se zabývá vlivem komplexně sdružené dvojice nul na vlastnosti přenosu.     

Komplexně sdružený pól a "jednoduchá" nula přenosu

Toto je jednoduchý příklad reálného přenosu (stupeň čitatele je menší než stupeň jmenovatele) s nulou v pravé nebo levé polorovině a koplexně sdruženým pólem.

>    P:=(p-p1)/(p-p2)/(p-p3);

P := (p-p1)/((p-p2)*(p-p3))

Např. pro   p1 = -1000 , p2 = -20+I*100  a p3 = -20-I*100  dostaneme

>    pt:=invlaplace(P, p, t);
Re_pt:=evalc(Re(subs({p1=-1000,p2=-20+I*100,p3=-20-I*100},pt)));
Re2_pt:=evalc(Re(subs({p1=1000,p2=-20+I*100,p3=-20-I*100},pt)));
plot(subs({p1=-1000,p2=-20+I*100,p3=-20-I*100},pt),t=0..0.3,title=`Impulzní charakteristika (nula vlevo)`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],thickness=3);
plot(subs({p1=1000,p2=-20+I*100,p3=-20-I*100},pt),t=0..0.3,title=`Impulzní charakteristika (nula vpravo)`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],thickness=3);

pt := exp(p2*t)*p1/(-p2+p3)-exp(p2*t)*p2/(-p2+p3)+exp(p3*t)*p3/(-p2+p3)-exp(p3*t)*p1/(-p2+p3)

Re_pt := exp(-20*t)*cos(100*t)+49/5*exp(-20*t)*sin(100*t)

Re2_pt := exp(-20*t)*cos(100*t)-51/5*exp(-20*t)*sin(100*t)

[Maple Plot]

[Maple Plot]

Jak je vidět z výše uvedených vztahů a z těchto obrázků, poloha nuly nemá vliv na stabilitu obvodu, pouze poněkud změní tvar signálu odezvy. Charakter odezvy je dán chrakterem pólů přenosu. Vzhledem k jednoduchosti příkladu a z toho co již bylo prezentováno se zde nebudeme zabývat kmitočtyovými vlastnostmi přenosu. V poslední ukázce je příklad přenosu s dvěmi nulami a dvěma póly. Na něm je demonstrován vliv komplexní dvojice nul na chování obvodu (v časové i kmitočtové oblasti).

Komplexně sdružená dvojice nul přenosu

Zde je ukázán vliv komplexně sdručených nul přenosu na jeho vlastnosti.

>    P:=(p-p1)*(p-p2)/(p-p3)/(p-p4);

P := (p-p1)*(p-p2)/((p-p3)*(p-p4))

  Např. pro   p1 = -100-I*2000 , p2 = -100+I*2000 , p3 = -200  a p4 = -100  dostaneme

>    pt:=invlaplace(P, p, t):
Re_pt:=evalc(Re(subs({p1=-100-2000*I,p2=-100+2000*I,p3=-200,p4=-100},pt)));
Im_pt:=evalc(Im(subs({p1=-100-2000*I,p2=-100+2000*I,p3=-200,p4=-100},pt)));
plot(evalc(subs({p1=-100+2000*I,p2=-100-2000*I,p3=-200,p4=-100},pt)),t=0.00001..0.3,title=`Impulzní charakteristika`,labelfont=[HELVETICA,8],axesfont=[HELVETICA,8],thickness=3);

Re_pt := Dirac(t)-40100*exp(-200*t)+40000*exp(-100*t)

Im_pt := 0

[Maple Plot]

Jak je vidět z tohoto výpočtu a následného grafu a jak již bylo předesláno, nemá koplexně sdružená dvojice nul vliv na na charakter časové odezvy (impulzní charakteristiky).   

>    semilogplot(20*log10(evalc(abs(subs({p1=-100-2000*I,p2=-100+2000*I,p3=-200,p4=-100,p=I*omega},P)))),omega=50..10000,title=`Modulová charakteristika [dB]`,labels=[omega,`log|P|`], axes=FRAME,labelfont=[HELVETICA,8], axesfont=[HELVETICA,8],thickness=3);
semilogplot(180/Pi*argument(subs({p1=-100-2000*I,p2=-100+2000*I,p3=-200,p4=-100,p=I*omega},P)),omega=50..10000,title=`Fázová charakteristika [deg]`,labels=[omega,`Arg(P)`], axes=FRAME,labelfont=[HELVETICA,8], axesfont=[HELVETICA,8],thickness=3);

[Maple Plot]

[Maple Plot]

>    Pss:=evalf(20*log10(limit(subs({p1=-100-2000*I,p2=-100+2000*I,p3=-200,p4=-100},P),p=0)));

>    Pn:=evalf(20*log10(limit(abs(subs({p1=-100-2000*I,p2=-100+2000*I,p3=-200,p4=-100,p=I*omega},P)),omega=infinity)));

>    Q:=evalf(1/2*sqrt(100^2+2000^2)/100);

Pss := 46.04228754

Pn := 0.

Q := 10.01249220

>    evalf(sqrt(2000^2+100^2));

2002.498440

Průběh modulové charakteristiky vychází podle našeho očekávání. Pro stejnosměrné buzení vykazuje zesílení Pss = 46  dB, na úhlovém kmmitočtu 100 a 200 [1/s] jsou dva póly, tudíž zde modul klesá. Vlivem komplexně sdružené dvojici nul přenos potom v okolí kmitočtu 2002 [1/s] ( omega[0] = sqrt(2000^2+100^2) ) dochází ke dvojnásobnému zlomu s "překmitem"  o 20dB ( Q = 10 ) a chrakteristika již dále není závislá na kmitočtu. Pro velmi vysoké kmitočty se blíží k hodnotě Pn = 0  dB. Fázová chrakteristika vykazuje opět předpokládaný průběh. Nejdříve vlivem pólů klesá z nuly až k hodnotě -180^o . Této hodnoty však nedosáhne, jelikož se začne uplatňovat vliv komplexně sdružených nul se zápornou reálnou částí. Jejich vlivem fáze opět vemi strmě stoupá až k hodnotě 0^o .  Čtenář si může sám ověřit, že průběh modulové charakteristiky se nezmění pro stejný příklad, ale s umístěním komplexně sdružených nul v pravé polorovině (s kladnou reálnou částí). Víme již také, že v tom případě by fáze vlivem těchto nul nestoupala, ale dále klesala až do hodnoty 360 = 0^o .

Dodělat  aplikace ve filtrech (eliptivké sekce), tj. komplexně sdružená nula na imaginární ose --  NOTCH a ES_LP a ES_HP.